_INSTANTIATING CODE PATTERNS_
by Fred Wild

Listing Two

#   Create the header file ...
#
                :$$NEWFILE <dsm.name>.hxx
                :
                :#ifndef <dsm.name>_H
                :#define <dsm.name>_H
                :
                :// Forward references for each class
                :
.EAch_obj
                :class  <obj.name> ;
.ENd
                :
                :$$EXECMODULE emit_class_decls
                :
                :#endif
                :
#   Create the body file ...
#
                :$$NEWFILE <dsm.name>.cxx
                :
                :#include "<dsm.name>.hxx"
                :
                :$$EXECMODULE emit_class_bodies
                :
###################################################################
#   Module to emit class declarations
#
.MOdule emit_class_decls
.EAch_obj
                        :
                        ://
                        ://  Class <obj.name> --------------------------------
                        ://
                        :
                        :class <obj.name> \
<obj.has_parent>        :: \
.EAch_parent
                        :<parent.name>\
<!parent.is_nth>        :, 
<parent.is_nth>         : 
.ENd
                        :{
                        :$$EXECMODULE emit_member_variables
                        :
                        :   public:
                        :
                        :       <obj.name>();
                        :       <obj.name>(const <obj.name>& obj);
                        :       <obj.name> *makeCopy() const ;
                        :       virtual ~<obj.name>();
                        :
                        :       <obj.name> &operator=(const <obj.name> &rhs) ;
                        :
                        :$$EXECMODULE emit_attr_access_ftn_decls
                        :
                        :} ;
.ENd
.ENd

###################################################################
#   Modules to emit class member variable declarations
#
.MOdule emit_member_variables
.EAch_attr
<attr.simple>       :       <attr.kind>       <30>  m_<attr.name> ;
<attr.ptr_to>       :       <attr.kind>       <30> *m_<attr.name> ;
.ENd
.ENd

###################################################################
#   Module to emit attribute access function declarations
#
.MOdule emit_attr_access_ftn_decls
.EAch_attr
                    :$$EXECMODULE emit_get_decl
                    :$$EXECMODULE emit_set_decl
                    :
.ENd
.ENd

###################################################################
#   Module to emit get functions for an attribute
#
.MOdule emit_get_decl
<attr.simple><!attr.use_ref> : <attr.kind>   <35>Get<attr.name> () const ;
<attr.simple><attr.use_ref>  : const <attr.kind> & <35>Get<attr.name> () const;
<attr.ptr_to>                : const <attr.kind> * <35>Get<attr.name> () const;
.ENd

###################################################################
#   Module to emit set functions for an attribute
#
.MOdule emit_set_decl
<attr.simple><!attr.use_ref> : void <35>Set<attr.name>(const<attr.kind> val);
<attr.simple><attr.use_ref>  : void <35>Set<attr.name>(const<attr.kind> & val);
<attr.ptr_to>                : void <35>Set<attr.name>(<attr.kind> *val) ; 
<attr.ptr_to>                : void <35>Clear<attr.name> () ; 
.ENd

###################################################################
#   Module to emit the bodies of member functions for each class
#
.MOdule emit_class_bodies
.EAch_obj
            :
            ://////////////////////////////////////////////////////////
            ://     class <obj.name>

            :$$EXECMODULE emit_class_default_ctor
            :$$EXECMODULE emit_class_copy_ctor
            :$$EXECMODULE emit_class_destructor
            :$$EXECMODULE emit_assignment_op_body
            :$$EXECMODULE emit_get_and_set_ftn_bodies
.ENd
.ENd

###################################################################
#   Module to create a class' default constructor
#
.MOdule emit_class_default_ctor
                                 :
                                 :<obj.name>::<obj.name>()
                                 :{
.EAch_attr
<attr.ptr_to><!attr.has_init>    :   m_<attr.name> = NULL;
<attr.has_init>                  :   m_<attr.name> = <attr.init_val> ;
.ENd
                                 :}
.ENd

###################################################################
#   Module to create a class' copy ctor and 'makeCopy' function
#
.MOdule emit_class_copy_ctor
                                 :
                                 :<obj.name>::<obj.name>(const <obj.name>& obj)
<obj.has_parent>                 :   : \

.EAch_parent
                                 :<parent.name>(obj)\
<!parent.is_nth>                 :,
<!parent.is_nth>                 :     \
<parent.is_nth>                  :
.ENd
                                 :{
.EAch_attr
<attr.simple>                  : m_<attr.name> = obj.m_<attr.name>;
<attr.ptr_to><attr.is_shared>  : m_<attr.name> = obj.m_<attr.name>;
<attr.ptr_to><attr.is_owner>   : m_<attr.name> = obj.m_<attr.name>->makeCopy();
.ENd
                                 :}
                                 :
                                 :<obj.name> *<obj.name>::makeCopy() const 
                                 :{
                                 :    return new <obj.name>(*this);
                                 :}
.ENd

###################################################################
#   Module to create a class' destructor
#
.MOdule emit_class_destructor
                                 :
                                 :<obj.name>::~<obj.name>()
                                 :{
.EAch_attr
<attr.ptr_to><attr.is_owner>     :   delete m_<attr.name> ;
.ENd
                                 :}
.ENd

###################################################################
#   Module to create a class' assignment operator
#
.MOdule emit_assignment_op_body
                                :
                                :<obj.name> &
                                :<obj.name>::operator=(const <obj.name> &rhs)
                                :{
                                :   if (this == &rhs) return *this ;
                                :       // No changes if assignment to self 
                                :
.EAch_parent
                                :   ((<parent.name> &) (*this)) = rhs ;  
                                :       // Assign base class members of <parent.name>
.ENd
.EAch_attr
<attr.simple>                  : m_<attr.name> = rhs.m_<attr.name>;
<attr.ptr_to><attr.is_shared>  : m_<attr.name> = rhs.m_<attr.name>;
<attr.ptr_to><attr.is_owner>   : m_<attr.name> = rhs.m_<attr.name>->makeCopy();
.ENd
                                :
                                :   return *this ;
                                :}
.ENd

###################################################################
# Module to create class member functions that access single valued member vars
#
.MOdule emit_get_and_set_ftn_bodies
.EAch_attr
<attr.getset>   :$$EXECMODULE emit_get_ftn_body
<attr.getset>   :$$EXECMODULE emit_set_and_clear_ftn_bodies
.ENd
.ENd

###################################################################
#   Module to create a 'Get' function body for accessing an attribute
#
.MOdule emit_get_ftn_body
<attr.simple><!attr.use_ref>    :<attr.kind> Get<attr.name> () const
<attr.simple><attr.use_ref>     :const <attr.kind> & Get<attr.name> () const 
<attr.ptr_to>                   :const <attr.kind> * Get<attr.name> () const 
                                :{
                                :    return m_<attr.name> ;
                                :}
.ENd

###################################################################
#   Module to create a 'Set' and 'Clear' function bodies
#
.MOdule emit_set_and_clear_ftn_bodies
<attr.simple><!attr.use_ref>    :void Set<attr.name> (const <attr.kind> val)
<attr.simple><attr.use_ref>     :void Set<attr.name> (const <attr.kind> & val)
<attr.ptr_to>                   :void Set<attr.name> (<attr.kind> *val)
                                :{
<attr.simple>                   :  <attr.name> = val ;
<attr.ptr_to><attr.is_owner>    :  if (<attr.name> != NULL) delete <attr.name>;
<attr.ptr_to>                   :  <attr.name> = val ;
                                :}
<attr.ptr_to>                   :
<attr.ptr_to>                   :
<attr.ptr_to>                   :void Clear<attr.name> ()
<attr.ptr_to>                   :{
<attr.ptr_to><attr.is_owner>    : if (<attr.name> != NULL) delete <attr.name> ;
<attr.ptr_to>                   : <attr.name> = NULL ;
<attr.ptr_to>                   :}
.ENd
.ENd